On this page:
Any
Any  Values
Nothing
1.1 Base Types
1.1.1 Numeric Types
Number
Complex
Integer
Float
Flonum
Single-Flonum
Inexact-Real
Exact-Rational
Real
Exact-Number
Float-Complex
Single-Flonum-Complex
Inexact-Complex
Imaginary
Exact-Complex
Exact-Imaginary
Inexact-Imaginary
Positive-Integer
Exact-Positive-Integer
Nonnegative-Integer
Exact-Nonnegative-Integer
Natural
Negative-Integer
Nonpositive-Integer
Zero
Positive-Float
Positive-Flonum
Nonnegative-Float
Nonnegative-Flonum
Negative-Float
Negative-Flonum
Nonpositive-Float
Nonpositive-Flonum
Float-Negative-Zero
Flonum-Negative-Zero
Float-Positive-Zero
Flonum-Positive-Zero
Float-Zero
Flonum-Zero
Float-Nan
Flonum-Nan
Positive-Single-Flonum
Nonnegative-Single-Flonum
Negative-Single-Flonum
Nonpositive-Single-Flonum
Single-Flonum-Negative-Zero
Single-Flonum-Positive-Zero
Single-Flonum-Zero
Single-Flonum-Nan
Positive-Inexact-Real
Nonnegative-Inexact-Real
Negative-Inexact-Real
Nonpositive-Inexact-Real
Inexact-Real-Negative-Zero
Inexact-Real-Positive-Zero
Inexact-Real-Zero
Inexact-Real-Nan
Positive-Exact-Rational
Nonnegative-Exact-Rational
Negative-Exact-Rational
Nonpositive-Exact-Rational
Positive-Real
Nonnegative-Real
Negative-Real
Nonpositive-Real
Real-Zero
One
Byte
Positive-Byte
Index
Positive-Index
Fixnum
Positive-Fixnum
Nonnegative-Fixnum
Negative-Fixnum
Nonpositive-Fixnum
Ext  Flonum
Positive-Ext  Flonum
Nonnegative-Ext  Flonum
Negative-Ext  Flonum
Nonpositive-Ext  Flonum
Ext  Flonum-Negative-Zero
Ext  Flonum-Positive-Zero
Ext  Flonum-Zero
Ext  Flonum-Nan
1.1.2 Other Base Types
Boolean
True
False
String
Keyword
Symbol
Char
Void
Input-Port
Output-Port
Port
Path
Path-For-Some-System
Regexp
PRegexp
Byte-Regexp
Byte-PRegexp
Bytes
Namespace
Namespace-Anchor
Variable-Reference
Null
EOF
Continuation-Mark-Set
Undefined
Module-Path
Module-Path-Index
Resolved-Module-Path
Compiled-Module-Expression
Compiled-Expression
Internal-Definition-Context
Pretty-Print-Style-Table
Special-Comment
Struct-Type-Property
Impersonator-Property
Read-Table
Bytes-Converter
Parameterization
Custodian
Inspector
Security-Guard
UDP-Socket
TCP-Listener
Logger
Log-Receiver
Log-Level
Thread
Thread-Group
Subprocess
Place
Place-Channel
Semaphore
FSemaphore
Will-Executor
Pseudo-Random-Generator
Environment-Variables
Path-String
1.2 Singleton Types
1.3 Containers
Pairof
Listof
List
List*
MListof
MPairof
MPair  Top
Boxof
Box  Top
Vectorof
Immutable-Vectorof
Mutable-Vectorof
Vector
Immutable-Vector
Mutable-Vector
Fl  Vector
Ext  Fl  Vector
Fx  Vector
Vector  Top
Mutable-Vector  Top
Hash  Table
Immutable-Hash  Table
Mutable-Hash  Table
Weak-Hash  Table
Hash  Table  Top
Mutable-Hash  Table  Top
Weak-Hash  Table  Top
Setof
Channelof
Channel  Top
Async-Channelof
Async-Channel  Top
Parameterof
Promise
Futureof
Sequenceof
Sequence  Top
Custodian-Boxof
Thread-Cellof
Thread-Cell  Top
Weak-Boxof
Weak-Box  Top
Ephemeronof
Evtof
1.4 Syntax Objects
Syntaxof
Identifier
Syntax
Syntax-E
Sexpof
Sexp
Datum
1.5 Control
Prompt-Tagof
Prompt-Tag  Top
Continuation-Mark-Keyof
Continuation-Mark-Key  Top
1.6 Other Type Constructors
->
->*
Top
Bot
Procedure
U
case->
All
Values
Rec
Struct
Struct-Type
Struct-Type  Top
Prefab
Prefab  Top
Union
Intersection
case→
1.7 Other Types
Option
Opaque
7.4.0.1

1 Type Reference

syntax

Any

Any Racket value. All other types are subtypes of Any.

syntax

AnyValues

Any number of Racket values of any type.

syntax

Nothing

The empty type. No values inhabit this type, and any expression of this type will not evaluate to a value.

1.1 Base Types

1.1.1 Numeric Types

These types represent the hierarchy of numbers of Racket. The diagram below shows the relationships between the types in the hierarchy.

image

The regions with a solid border are layers of the numeric hierarchy corresponding to sets of numbers such as integers or rationals. Layers contained within another are subtypes of the layer containing them. For example, Exact-Rational is a subtype of Exact-Number.

The Real layer is also divided into positive and negative types (shown with a dotted line). The Integer layer is subdivided into several fixed-width integers types, detailed later in this section.

syntax

Number

syntax

Complex

Number and Complex are synonyms. This is the most general numeric type, including all Racket numbers, both exact and inexact, including complex numbers.

syntax

Integer

Includes Racket’s exact integers and corresponds to the exact-integer? predicate. This is the most general type that is still valid for indexing and other operations that require integral values.

syntax

Float

syntax

Flonum

Includes Racket’s double-precision (default) floating-point numbers and corresponds to the flonum? predicate. This type excludes single-precision floating-point numbers.

Includes Racket’s single-precision floating-point numbers and corresponds to the single-flonum? predicate. This type excludes double-precision floating-point numbers.

Includes all of Racket’s floating-point numbers, both single- and double-precision.

Includes Racket’s exact rationals, which include fractions and exact integers.

syntax

Real

Includes all of Racket’s real numbers, which include both exact rationals and all floating-point numbers. This is the most general type for which comparisons (e.g. <) are defined.

These types correspond to Racket’s complex numbers.

Changed in version 1.7 of package typed-racket-lib: Added Imaginary, Inexact-Complex, Exact-Complex, Exact-Imaginary, Inexact-Imaginary.

The above types can be subdivided into more precise types if you want to enforce tighter constraints. Typed Racket provides types for the positive, negative, non-negative and non-positive subsets of the above types (where applicable).

Natural and Exact-Nonnegative-Integer are synonyms. So are the integer and exact-integer types, and the float and flonum types. Zero includes only the integer 0. Real-Zero includes exact 0 and all the floating-point zeroes.

These types are useful when enforcing that values have a specific sign. However, programs using them may require additional dynamic checks when the type-checker cannot guarantee that the sign constraints will be respected.

In addition to being divided by sign, integers are further subdivided into range-bounded types. The relationships between most of the range-bounded types are shown in this diagram:

image

Like the previous diagram, types nested inside of another in the diagram are subtypes of its containing types.

One includes only the integer 1. Byte includes numbers from 0 to 255. Index is bounded by 0 and by the length of the longest possible Racket vector. Fixnum includes all numbers represented by Racket as machine integers. For the latter two families, the sets of values included in the types are architecture-dependent, but typechecking is architecture-independent.

These types are useful to enforce bounds on numeric values, but given the limited amount of closure properties these types offer, dynamic checks may be needed to check the desired bounds at runtime.

Examples:
> 7

- : Integer [more precisely: Positive-Byte]

7

> 8.3

- : Flonum [more precisely: Positive-Float-No-NaN]

8.3

> (/ 8 3)

- : Exact-Rational [more precisely: Positive-Exact-Rational]

8/3

> 0

- : Integer [more precisely: Zero]

0

> -12

- : Integer [more precisely: Negative-Fixnum]

-12

> 3+4i

- : Exact-Number

3+4i

80-bit extflonum types, for the values operated on by racket/extflonum exports. These are not part of the numeric tower.

1.1.2 Other Base Types

These types represent primitive Racket data.

Examples:
> #t

- : Boolean [more precisely: True]

#t

> #f

- : False

#f

> "hello"

- : String

"hello"

> (current-input-port)

- : Input-Port

#<input-port:string>

> (current-output-port)

- : Output-Port

#<output-port:string>

> (string->path "/")

- : Path

#<path:/>

> #rx"a*b*"

- : Regexp

#rx"a*b*"

> #px"a*b*"

- : PRegexp

#px"a*b*"

> '#"bytes"

- : Bytes

#"bytes"

> (current-namespace)

- : Namespace

#<namespace>

> #\b

- : Char

#\b

> (thread (lambda () (add1 7)))

- : Thread

#<thread>

The union of the Path and String types. Note that this does not match exactly what the predicate path-string? recognizes. For example, strings that contain the character #\nul have the type Path-String but path-string? returns #f for those strings. For a complete specification of which strings path-string? accepts, see its documentation.

1.2 Singleton Types

Some kinds of data are given singleton types by default. In particular, booleans, symbols, and keywords have types which consist only of the particular boolean, symbol, or keyword. These types are subtypes of Boolean, Symbol and Keyword, respectively.

Examples:
> #t

- : Boolean [more precisely: True]

#t

> '#:foo

- : '#:foo

'#:foo

> 'bar

- : Symbol [more precisely: 'bar]

'bar

1.3 Containers

The following base types are parametric in their type arguments.

syntax

(Pairof s t)

is the pair containing s as the car and t as the cdr

Examples:
> (cons 1 2)

- : (Pairof One Positive-Byte)

'(1 . 2)

> (cons 1 "one")

- : (Pairof One String)

'(1 . "one")

syntax

(Listof t)

Homogeneous lists of t

syntax

(List t ...)

is the type of the list with one element, in order, for each type provided to the List type constructor.

syntax

(List t ... trest ... bound)

is the type of a list with one element for each of the ts, plus a sequence of elements corresponding to trest, where bound must be an identifier denoting a type variable bound with ....

syntax

(List* t t1 ... s)

is equivalent to (Pairof t (List* t1 ... s)).

Examples:
> (list 'a 'b 'c)

- : (Listof (U 'a 'b 'c)) [more precisely: (List 'a 'b 'c)]

'(a b c)

> (plambda: (a ...) ([sym : Symbol] boxes : (Boxof a) ... a)
    (ann (cons sym boxes) (List Symbol (Boxof a) ... a)))

- : (All (a ...)

      (-> Symbol (Boxof a) ... a (Pairof Symbol (List (Boxof a) ... a))))

#<procedure>

> (map symbol->string (list 'a 'b 'c))

- : (Listof String) [more precisely: (Pairof String (Listof String))]

'("a" "b" "c")

syntax

(MListof t)

Homogeneous mutable lists of t.

syntax

(MPairof t u)

Mutable pairs of t and u.

syntax

MPairTop

is the type of a mutable pair with unknown element types and is the supertype of all mutable pair types. This type typically appears in programs via the combination of occurrence typing and mpair?.

Example:
> (lambda: ([x : Any]) (if (mpair? x) x (error "not an mpair!")))

- : (-> Any MPairTop)

#<procedure>

syntax

(Boxof t)

A box of t

Example:
> (box "hello world")

- : (Boxof String)

'#&"hello world"

syntax

BoxTop

is the type of a box with an unknown element type and is the supertype of all box types. Only read-only box operations (e.g. unbox) are allowed on values of this type. This type typically appears in programs via the combination of occurrence typing and box?.

Example:
> (lambda: ([x : Any]) (if (box? x) x (error "not a box!")))

- : (-> Any BoxTop)

#<procedure>

syntax

(Vectorof t)

Homogeneous vectors of t (mutable or immutable).
Homogeneous immutable vectors of t.

Added in version 1.9 of package typed-racket-lib.

syntax

(Mutable-Vectorof t)

Homogeneous mutable vectors of t.

Added in version 1.9 of package typed-racket-lib.

syntax

(Vector t ...)

is the type of a mutable or immutable vector with one element, in order, for each type provided to the Vector type constructor.

Example:
> (ann (vector 1 'A) (Vector Fixnum 'A))

- : (U (Immutable-Vector Fixnum 'A) (Mutable-Vector Fixnum 'A))

'#(1 A)

syntax

(Immutable-Vector t ...)

similar to (Vector t ...), but for immutable vectors.

Example:
> (vector-immutable 1 2 3)

- : (U (Immutable-Vector One Positive-Byte Positive-Byte)

       (Mutable-Vector One Positive-Byte Positive-Byte)) [more precisely: (Immutable-Vector One Positive-Byte Positive-Byte)]

'#(1 2 3)

Added in version 1.9 of package typed-racket-lib.

syntax

(Mutable-Vector t ...)

similar to (Vector t ...), but for mutable vectors.

Example:
> (vector 1 2 3)

- : (U (Immutable-Vector Integer Integer Integer)

       (Mutable-Vector Integer Integer Integer)) [more precisely: (Mutable-Vector Integer Integer Integer)]

'#(1 2 3)

Added in version 1.9 of package typed-racket-lib.

syntax

FlVector

Example:
> (flvector 1.0 2.0 3.0)

- : FlVector

(flvector 1.0 2.0 3.0)

Example:
> (extflvector 1.0t0 2.0t0 3.0t0)

- : ExtFlVector

#<extflvector>

syntax

FxVector

Example:
> (fxvector 1 2 3)

- : FxVector

(fxvector 1 2 3)

syntax

VectorTop

is the type of a vector with unknown length and element types and is the supertype of all vector types. Only read-only vector operations (e.g. vector-ref) are allowed on values of this type. This type typically appears in programs via the combination of occurrence typing and vector?.

Example:
> (lambda: ([x : Any]) (if (vector? x) x (error "not a vector!")))

- : (-> Any VectorTop)

#<procedure>

is the type of a mutable vector with unknown length and element types.

syntax

(HashTable k v)

is the type of a mutable or immutable hash table with key type k and value type v.

Example:
> (make-hash '((a . 1) (b . 2)))

- : (HashTable Symbol Integer) [more precisely: (Mutable-HashTable Symbol Integer)]

'#hash((a . 1) (b . 2))

syntax

(Immutable-HashTable k v)

The type of an immutable hash table with key type k and value type v.

Example:
> #hash((a . 1) (b . 2))

- : (HashTable Symbol Integer) [more precisely: (Immutable-HashTable Symbol Integer)]

'#hash((a . 1) (b . 2))

Added in version 1.8 of package typed-racket-lib.

syntax

(Mutable-HashTable k v)

The type of a mutable hash table that holds keys strongly (see Weak Boxes) with key type k and value type v.

Example:
> (make-hash '((a . 1) (b . 2)))

- : (HashTable Symbol Integer) [more precisely: (Mutable-HashTable Symbol Integer)]

'#hash((a . 1) (b . 2))

Added in version 1.8 of package typed-racket-lib.

syntax

(Weak-HashTable k v)

The type of a mutable hash table that holds keys weakly with key type k and value type v.

Example:
> (make-weak-hash '((a . 1) (b . 2)))

- : (HashTable Symbol Integer) [more precisely: (Weak-HashTable Symbol Integer)]

'#hash((b . 2) (a . 1))

Added in version 1.8 of package typed-racket-lib.

is the type of a hash table with unknown key and value types and is the supertype of all hash table types. Only read-only hash table operations (e.g. hash-ref) are allowed on values of this type. This type typically appears in programs via the combination of occurrence typing and hash?.

Example:
> (lambda: ([x : Any]) (if (hash? x) x (error "not a hash table!")))

- : (-> Any HashTableTop)

#<procedure>

is the type of a mutable hash table that holds keys strongly with unknown key and value types.

is the type of a mutable hash table that holds keys weakly with unknown key and value types.

syntax

(Setof t)

is the type of a hash set of t. This includes custom hash sets, but not mutable hash set or sets that are implemented using gen:set.

Example:
> (set 0 1 2 3)

- : (Setof Byte)

(set 1 3 0 2)

Example:
> (seteq 0 1 2 3)

- : (Setof Byte)

(seteq 0 1 2 3)

syntax

(Channelof t)

A channel on which only ts can be sent.

Example:
> (ann (make-channel) (Channelof Symbol))

- : (Channelof Symbol)

#<channel>

is the type of a channel with unknown message type and is the supertype of all channel types. This type typically appears in programs via the combination of occurrence typing and channel?.

Example:
> (lambda: ([x : Any]) (if (channel? x) x (error "not a channel!")))

- : (-> Any ChannelTop)

#<procedure>

syntax

(Async-Channelof t)

An asynchronous channel on which only ts can be sent.

Examples:
> (require typed/racket/async-channel)
> (ann (make-async-channel) (Async-Channelof Symbol))

- : (Async-Channelof Symbol)

#<async-channel>

Added in version 1.1 of package typed-racket-lib.

is the type of an asynchronous channel with unknown message type and is the supertype of all asynchronous channel types. This type typically appears in programs via the combination of occurrence typing and async-channel?.

Examples:
> (require typed/racket/async-channel)
> (lambda: ([x : Any]) (if (async-channel? x) x (error "not an async-channel!")))

- : (-> Any Async-ChannelTop)

#<procedure>

Added in version 1.1 of package typed-racket-lib.

syntax

(Parameterof t)

(Parameterof s t)
A parameter of t. If two type arguments are supplied, the first is the type the parameter accepts, and the second is the type returned.

Examples:
> current-input-port

- : (Parameterof Input-Port)

#<procedure:current-input-port>

> current-directory

- : (Parameterof Path-String Path)

#<procedure:current-directory>

syntax

(Promise t)

A promise of t.

Example:
> (delay 3)

- : (Promise Positive-Byte)

#<promise:eval:52:0>

syntax

(Futureof t)

A future which produce a value of type t when touched.

syntax

(Sequenceof t t ...)

A sequence that produces (Values t t ...) on each iteration. E.g., (Sequenceof String) is a sequence of strings, (Sequenceof Number String) is a sequence which produces two values—a number and a string—on each iteration, etc.

is the type of a sequence with unknown element type and is the supertype of all sequences. This type typically appears in programs via the combination of ocurrence typing ang sequence?.

Example:
> (lambda: ([x : Any]) (if (sequence? x) x (error "not a sequence!")))

- : (-> Any SequenceTop)

#<procedure>

Added in version 1.10 of package typed-racket-lib.

syntax

(Custodian-Boxof t)

A custodian box of t.

syntax

(Thread-Cellof t)

A thread cell of t.
is the type of a thread cell with unknown element type and is the supertype of all thread cell types. This type typically appears in programs via the combination of occurrence typing and thread-cell?.

Example:
> (lambda: ([x : Any]) (if (thread-cell? x) x (error "not a thread cell!")))

- : (-> Any Thread-CellTop)

#<procedure>

syntax

(Weak-Boxof t)

The type for a weak box whose value is of type t.

Examples:
> (make-weak-box 5)

- : (Weak-Boxof Integer)

#<weak-box>

> (weak-box-value (make-weak-box 5))

- : (U False Integer)

5

is the type of a weak box with an unknown element type and is the supertype of all weak box types. This type typically appears in programs via the combination of occurrence typing and weak-box?.

Example:
> (lambda: ([x : Any]) (if (weak-box? x) x (error "not a box!")))

- : (-> Any Weak-BoxTop)

#<procedure>

syntax

(Ephemeronof t)

An ephemeron whose value is of type t.

syntax

(Evtof t)

Examples:
> always-evt

- : (Rec x (Evtof x))

#<always-evt>

> (system-idle-evt)

- : (Evtof Void)

#<evt>

> (ann (thread (λ () (displayln "hello world"))) (Evtof Thread))

- : (Evtof Thread)

hello world

#<thread>

1.4 Syntax Objects

The following types represent syntax objects and their content.

syntax

(Syntaxof t)

A syntax object with content of type t. Applying syntax-e to a value of type (Syntaxof t) produces a value of type t.

A syntax object containing a symbol. Equivalent to (Syntaxof Symbol).

syntax

Syntax

A syntax object containing only symbols, keywords, strings, characters, booleans, numbers, boxes containing Syntax, vectors of Syntax, or (possibly improper) lists of Syntax. Equivalent to (Syntaxof Syntax-E).

syntax

Syntax-E

The content of syntax objects of type Syntax. Applying syntax-e to a value of type Syntax produces a value of type Syntax-E.

syntax

(Sexpof t)

The recursive union of t with symbols, keywords, strings, characters, booleans, numbers, boxes, vectors, and (possibly improper) lists.

syntax

Sexp

Applying syntax->datum to a value of type Syntax produces a value of type Sexp. Equivalent to (Sexpof Nothing).

syntax

Datum

Applying datum->syntax to a value of type Datum produces a value of type Syntax. Equivalent to (Sexpof Syntax).

1.5 Control

The following types represent prompt tags and keys for continuation marks for use with delimited continuation functions and continuation mark functions.

syntax

(Prompt-Tagof s t)

A prompt tag to be used in a continuation prompt whose body produces the type s and whose handler has the type t. The type t must be a function type.

The domain of t determines the type of the values that can be aborted, using abort-current-continuation, to a prompt with this prompt tag.

Example:
> (make-continuation-prompt-tag 'prompt-tag)

- : (Prompt-Tagof Any Any)

#<continuation-prompt-tag:prompt-tag>

is the type of a prompt tag with unknown body and handler types and is the supertype of all prompt tag types. This type typically appears in programs via the combination of occurrence typing and continuation-prompt-tag?.

Example:
> (lambda: ([x : Any]) (if (continuation-prompt-tag? x) x (error "not a prompt tag!")))

- : (-> Any Prompt-TagTop)

#<procedure>

A continuation mark key that is used for continuation mark operations such as with-continuation-mark and continuation-mark-set->list. The type t represents the type of the data that is stored in the continuation mark with this key.

Example:
> (make-continuation-mark-key 'mark-key)

- : (Continuation-Mark-Keyof Any)

#<continuation-mark-key>

is the type of a continuation mark key with unknown element type and is the supertype of all continuation mark key types. This type typically appears in programs via the combination of occurrence typing and continuation-mark-key?.

Example:
> (lambda: ([x : Any]) (if (continuation-mark-key? x) x (error "not a mark key!")))

- : (-> Any Continuation-Mark-KeyTop)

#<procedure>

1.6 Other Type Constructors

syntax

(-> dom ... rng opt-proposition)

(-> dom ... rest * rng)
(-> dom ... rest ooo bound rng)
(dom ... -> rng opt-proposition)
(dom ... rest * -> rng)
(dom ... rest ooo bound -> rng)
 
ooo = ...
     
dom = type
  | mandatory-kw
  | opt-kw
     
rng = type
  | (Values type ...)
     
mandatory-kw = keyword type
     
opt-kw = [keyword type]
     
opt-proposition = 
  | : type
  | 
: pos-proposition
  neg-proposition
  object
     
pos-proposition = 
  | #:+ proposition ...
     
neg-proposition = 
  | #:- proposition ...
     
object = 
  | #:object index
     
proposition = Top
  | Bot
  | type
  | (! type)
  | (type @ path-elem ... index)
  | (! type @ path-elem ... index)
  | (and proposition ...)
  | (or proposition ...)
  | (implies proposition ...)
     
path-elem = car
  | cdr
     
index = positive-integer
  | (positive-integer positive-integer)
  | identifier
The type of functions from the (possibly-empty) sequence dom .... to the rng type.

Examples:
> (λ ([x : Number]) x)

- : (-> Number Number)

#<procedure>

> (λ () 'hello)

- : (-> 'hello)

#<procedure>

The second form specifies a uniform rest argument of type rest, and the third form specifies a non-uniform rest argument of type rest with bound bound. The bound refers to the type variable that is in scope within the rest argument type.

Examples:
> (λ ([x : Number]    y : String *)  (length y))

- : (-> Number String * Index)

#<procedure>

> ormap

- : (All (a c b ...)

      (-> (-> a b ... b c) (Listof a) (Listof b) ... b (U False c)))

#<procedure:ormap>

In the third form, the ... introduced by ooo is literal, and bound must be an identifier denoting a type variable.

The doms can include both mandatory and optional keyword arguments. Mandatory keyword arguments are a pair of keyword and type, while optional arguments are surrounded by a pair of parentheses.

Examples:
> (:print-type file->string)

(-> Path-String [#:mode (U 'binary 'text)] String)

> (: is-zero? : (-> Number #:equality (-> Number Number Any) [#:zero Number] Any))
> (define (is-zero? n #:equality equality #:zero [zero 0])
    (equality n zero))
> (is-zero? 2 #:equality =)

- : Any

#f

> (is-zero? 2 #:equality eq? #:zero 2.0)

- : Any

#f

When opt-proposition is provided, it specifies the proposition for the function type (for an introduction to propositions in Typed Racket, see Propositions and Predicates). For almost all use cases, only the simplest form of propositions, with a single type after a :, are necessary:

Example:
> string?

- : (-> Any Boolean : String)

#<procedure:string?>

The proposition specifies that when (string? x) evaluates to a true value for a conditional branch, the variable x in that branch can be assumed to have type String. Likewise, if the expression evaluates to #f in a branch, the variable does not have type String.

In some cases, asymmetric type information is useful in the propositions. For example, the filter function’s first argument is specified with only a positive proposition:

Example:
> filter

- : (All (a b)

      (case->

       (-> (-> a Any : #:+ b) (Listof a) (Listof b))

       (-> (-> a Any) (Listof a) (Listof a))))

#<procedure:filter>

The use of #:+ indicates that when the function applied to a variable evaluates to a true value, the given type can be assumed for the variable. However, the type-checker gains no information in branches in which the result is #f.

Conversely, #:- specifies that a function provides information for the false branch of a conditional.

The other proposition cases are rarely needed, but the grammar documents them for completeness. They correspond to logical operations on the propositions.

The type of functions can also be specified with an infix -> which comes immediately before the rng type. The fourth through sixth forms match the first three cases, but with the infix style of arrow.

Examples:
> (: add2 (Number -> Number))
> (define (add2 n) (+ n 2))

syntax

(->* (mandatory-dom ...) optional-doms rest rng)

 
mandatory-dom = type
  | keyword type
     
optional-doms = 
  | (optional-dom ...)
     
optional-dom = type
  | keyword type
     
rest = 
  | #:rest type
  | #:rest-star (type ...)
Constructs the type of functions with optional or rest arguments. The first list of mandatory-doms correspond to mandatory argument types. The list optional-doms, if provided, specifies the optional argument types.

Examples:
> (: append-bar (->* (String) (Positive-Integer) String))
> (define (append-bar str [how-many 1])
    (apply string-append str (make-list how-many "bar")))

If provided, the #:rest type specifies the type of elements in the rest argument list.

Examples:
> (: +all (->* (Integer) #:rest Integer (Listof Integer)))
> (define (+all inc . rst)
    (map (λ ([x : Integer]) (+ x inc)) rst))
> (+all 20 1 2 3)

- : (Listof Integer)

'(21 22 23)

A #:rest-star (type ...) specifies the rest list is a sequence of types which occurs 0 or more times (i.e. the Kleene closure of the sequence).

Examples:
> (: print-name+ages (->* () #:rest-star (String Natural) Void))
> (define (print-name+ages . names+ages)
    (let loop ([names+ages : (Rec x (U Null (List* String Natural x))) names+ages])
      (when (pair? names+ages)
        (printf "~a is ~a years old!\n"
                (first names+ages)
                (second names+ages))
        (loop (cddr names+ages))))
    (printf "done printing ~a ages" (/ (length names+ages) 2)))
> (print-name+ages)

done printing 0 ages

> (print-name+ages "Charlotte" 8 "Harrison" 5 "Sydney" 3)

Charlotte is 8 years old!

Harrison is 5 years old!

Sydney is 3 years old!

done printing 3 ages

Both the mandatory and optional argument lists may contain keywords paired with types.

Examples:
> (: kw-f (->* (#:x Integer) (#:y Integer) Integer))
> (define (kw-f #:x x #:y [y 0]) (+ x y))

The syntax for this type constructor matches the syntax of the ->* contract combinator, but with types instead of contracts.

syntax

Top

syntax

Bot

These are propositions that can be used with ->. Top is the propositions with no information. Bot is the propositions which means the result cannot happen.

syntax

Procedure

is the supertype of all function types. The Procedure type corresponds to values that satisfy the procedure? predicate. Because this type encodes only the fact that the value is a procedure, and not its argument types or even arity, the type-checker cannot allow values of this type to be applied.

For the types of functions with known arity and argument types, see the -> type constructor.

Examples:
> (: my-list Procedure)
> (define my-list list)
> (my-list "zwiebelkuchen" "socca")

eval:91:0: Type Checker: cannot apply a function with

unknown arity;

 function `my-list' has type Procedure which cannot be

applied

  in: "socca"

syntax

(U t ...)

is the union of the types t ....

Example:
> (λ ([x : Real]) (if (> 0 x) "yes" 'no))

- : (-> Real (U 'no String))

#<procedure>

syntax

( t ...)

is the intersection of the types t ....

Example:
> ((λ #:forall (A) ([x : ( Symbol A)]) x) 'foo)

- : Symbol [more precisely: 'foo]

'foo

syntax

(case-> fun-ty ...)

is a function that behaves like all of the fun-tys, considered in order from first to last. The fun-tys must all be non-dependent function types (i.e. no preconditions or dependencies between arguments are currently allowed).

Example:
> (: add-map : (case->
                 [(Listof Integer) -> (Listof Integer)]
                 [(Listof Integer) (Listof Integer) -> (Listof Integer)]))

For the definition of add-map look into case-lambda:.

syntax

(t t1 t2 ...)

is the instantiation of the parametric type t at types t1 t2 ...

syntax

(All (a ...) t)

(All (a ... a ooo) t)
is a parameterization of type t, with type variables a .... If t is a function type constructed with infix ->, the outer pair of parentheses around the function type may be omitted.

Examples:
> (: list-length : (All (A) (Listof A) -> Natural))
> (define (list-length lst)
    (if (null? lst)
        0
        (add1 (list-length (cdr lst)))))
> (list-length (list 1 2 3))

- : Integer [more precisely: Nonnegative-Integer]

3

syntax

(Values t ...)

is the type of a sequence of multiple values, with types t .... This can only appear as the return type of a function.

Example:
> (values 1 2 3)

- : (values Integer Integer Integer) [more precisely: (Values One Positive-Byte Positive-Byte)]

1

2

3

Note that a type variable cannot be instantiated with a (Values ....) type. For example, the type (All (A) (-> A)) describes a thunk that returns exactly one value.

syntax

v

where v is a number, boolean or string, is the singleton type containing only that value

syntax

(quote val)

where val is a Racket value, is the singleton type containing only that value

syntax

i

where i is an identifier can be a reference to a type name or a type variable

syntax

(Rec n t)

is a recursive type where n is bound to the recursive type in the body t

Examples:
> (define-type IntList (Rec List (Pair Integer (U List Null))))
> (define-type (List A) (Rec List (Pair A (U List Null))))

syntax

(Struct st)

is a type which is a supertype of all instances of the potentially-polymorphic structure type st. Note that structure accessors for st will not accept (Struct st) as an argument.

syntax

(Struct-Type st)

is a type for the structure type descriptor value for the structure type st. Values of this type are used with reflective operations such as struct-type-info.

Examples:
> struct:arity-at-least

- : (StructType arity-at-least)

#<struct-type:arity-at-least>

> (struct-type-info struct:arity-at-least)

- : (values

     Symbol

     Integer

     Integer

     (-> arity-at-least Nonnegative-Integer Any)

     (-> arity-at-least Nonnegative-Integer Nothing Void)

     (Listof Nonnegative-Integer)

     (U False Struct-TypeTop)

     Boolean)

[more precisely: (values

                  Symbol

                  Nonnegative-Integer

                  Nonnegative-Integer

                  (-> arity-at-least Nonnegative-Integer Any)

                  (-> arity-at-least Nonnegative-Integer Nothing Void)

                  (Listof Nonnegative-Integer)

                  (U False Struct-TypeTop)

                  Boolean)]

'arity-at-least

1

0

#<procedure:arity-at-least-ref>

#<procedure:arity-at-least-set!>

'(0)

#f

#f

is the supertype of all types for structure type descriptor values. The corresponding structure type is unknown for values of this top type.

Example:
> (struct-info (arity-at-least 0))

- : (values (U False Struct-TypeTop) Boolean)

#<struct-type:arity-at-least>

#f

syntax

(Prefab key type ...)

Describes a prefab structure with the given (implicitly quoted) prefab key key and specified field types.

Prefabs are more-or-less tagged polymorphic tuples which can be directly serialized and whose fields can be accessed by anyone. Subtyping is covariant for immutable fields and invariant for mutable fields.

When a prefab struct is defined with struct the struct name is bound at the type-level to the Prefab type with the corresponding key and field types and the constructor expects types corresponding to those declared for each field. The defined predicate, however, only tests whether a value is a prefab structure with the same key and number of fields, but does not inspect the fields’ values.

Examples:
> (struct person ([name : String]) #:prefab)
> person

- : (-> String person)

#<procedure:person>

> person?

- : (-> Any Boolean : (Prefab person Any))

#<procedure:person?>

> person-name

- : (All (x) (case-> (-> (Prefab person x) x) (-> (Prefab person Any) Any)))

#<procedure:person-name>

> (person "Jim")

- : person

'#s(person "Jim")

> (ann '#s(person "Dwight") person)

- : person

'#s(person "Dwight")

> (ann '#s(person "Pam") (Prefab person String))

- : person

'#s(person "Pam")

> (ann '#s(person "Michael") (Prefab person Any))

- : (Prefab person Any)

'#s(person "Michael")

> (person 'Toby)

eval:112:0: Type Checker: type mismatch

  expected: String

  given: 'Toby

  in: Toby

> (ann #s(person Toby) (Prefab person String))

eval:113:0: Type Checker: type mismatch

  expected: person

  given: (Prefab person 'Toby)

  in: String

> (ann '#s(person Toby) (Prefab person Symbol))

- : (Prefab person Symbol)

'#s(person Toby)

> (person? '#s(person "Michael"))

- : Boolean [more precisely: True]

#t

> (person? '#s(person Toby))

- : Boolean [more precisely: True]

#t

> (struct employee person ([schrute-bucks : Natural]) #:prefab)
> (employee "Oscar" 10000)

- : employee

'#s((employee person 1) "Oscar" 10000)

> (ann '#s((employee person 1)             "Oscar" 10000) employee)

- : employee

'#s((employee person 1) "Oscar" 10000)

> (ann '#s((employee person 1)             "Oscar" 10000)
       (Prefab (employee person 1) String Natural))

- : employee

'#s((employee person 1) "Oscar" 10000)

> (person? '#s((employee person 1)             "Oscar" 10000))

- : Boolean [more precisely: True]

#t

> (employee? '#s((employee person 1)             "Oscar" 10000))

- : Boolean [more precisely: True]

#t

> (employee 'Toby -1)

eval:123:0: Type Checker: type mismatch

  expected: String

  given: 'Toby

  in: -1

> (ann '#s((employee person 1)             Toby -1)
       (Prefab (employee person 1) Symbol Integer))

- : (Prefab (employee person 1) Symbol Integer)

'#s((employee person 1) Toby -1)

> (person? '#s((employee person 1)             Toby -1))

- : Boolean [more precisely: True]

#t

> (employee? '#s((employee person 1)             Toby -1))

- : Boolean [more precisely: True]

#t

syntax

(PrefabTop key field-count)

Describes all prefab types with the (implicitly quoted) prefab-key key and field-count many fields.

For immutable prefabs this is equivalent to (Prefab key Any ...) with field-count many occurrences of Any. For mutable prefabs, this describes a prefab that can be read from but not written to (since we do not know at what type other code may have the fields typed at).

Examples:
> (struct point ([x : Number] [y : Number])
    #:prefab
    #:mutable)
> point

- : (-> Number Number point)

#<procedure:point>

> point-x

- : (All (a b)

      (case->

       (-> (Prefab (point #(0 1)) a b) a)

       (-> (PrefabTop (point #(0 1)) 2) Any)))

#<procedure:point-x>

> point-y

- : (All (a b)

      (case->

       (-> (Prefab (point #(0 1)) a b) b)

       (-> (PrefabTop (point #(0 1)) 2) Any)))

#<procedure:point-y>

> point?

- : (-> Any Boolean : (PrefabTop (point #(0 1)) 2))

#<procedure:point?>

> (define (maybe-read-x p)
    (if (point? p)
        (ann (point-x p) Any)
        'not-a-point))
> (define (read-some-x-num p)
  (if (point? p)
      (ann (point-x p) Number)
      -1))

eval:133:0: Type Checker: Polymorphic function `point-x'

could not be applied to arguments:

Types: (PrefabTop (point #(0 1)) 2) -> Any

Arguments: (PrefabTop (point #(0 1)) 2)

Expected result: Number

  in: -1

Added in version 1.7 of package typed-racket-lib.

syntax

Union

An alias for U.
An alias for .

syntax

An alias for ->.

syntax

case→

An alias for case->.

syntax

An alias for All.

1.7 Other Types

syntax

(Option t)

Either t or #f

syntax

(Opaque t)

A type constructed using the #:opaque clause of require/typed.